# Script Name	: The Cabal's Backdoor Voider Script
# Author        : Traitor <traitor@tw-cabal.com> 
# Description   : Voids sectors to check them for backdoors. (more than 6
#		:   ways in)

# What it does	: This script pulls sector information from a file generated
#		:   by the "find_dock.ts" script.  It then reads in sector
#		:   numbers that match certain criteria and voids the
#		:   the surrounding sectors to check for sectors that have
#		:   more than 7 ways in.  It then generates a list that you
#		:   can walk through to find Class 0 ports and SD.

# Notes         : You must be at the Command Prompt for this script to work.
#		: THERE MAY BE SOME PAUSES WHERE IT LOOKS LIKE IT'S NOT DOING
#		:   ANYTHING.  THIS IS NORMAL.  BE PATIENT.  ARRAYS TAKE A WHILE
#		:   TO MAKE IN TWX.  ON MY 1.2 GHZ PC, ARRAYS CAN TAKE UP TO 
#		:   60 SECONDS TO READ IN.  IF YOU HAVE A SLOWER PC, THIS MAY
#		:   TAKE EVEN LONGER.  GET A CUP OF COFFEE OR SOMETHING.
#		: You should run this script after running find_dock.ts first.
#		: sdfind.txt (or whatever you call it) must be in the TWX directory.
#		: This script will create a new file called sdsector.txt in your
#		:   TWX subdirectory.  That file will contain the sector numbers
#		:   of sectors that have more than 7 ways in.  Those are usually
#		:   the SD and Class 0 ports.
#		: See the documentation contained in find_dock.ts for more
#		:   information.

# ----====[ show EGO banner :-) ]====----
#  If this really bugs you, feel free to remove this section. 
#  It creates a file on your system that checks to see if the banner has been
#  seen before.  The file is called banner_voider.txt and in your TWX directory
#  -Traitor
:bannercheck
fileexists $checkbanner "banner_voider.txt"
if $checkbanner = TRUE
goto :promptcheck
else
echo "**" ANSI_1 "            --" ANSI_9 "===|  " ANSI_11 "The Cabal's Backdoor Voider  v1.0.0" ANSI_9 "  |===" ANSI_1 "--*"
echo ANSI_1 "               --" ANSI_9 "===|  " ANSI_11 "Last edited November 24, 2002" ANSI_9 "  |===" ANSI_1 "--*"
echo ANSI_1 "                        --" ANSI_9 "===|  " ANSI_11 "By " ANSI_12 " Traitor" ANSI_9 "  |===" ANSI_1 "--*"
echo ANSI_1 "                --" ANSI_9 "===|  " ANSI_11 "E-Mail " ANSI_12 "traitor@tw-cabal.com" ANSI_9 "  |===" ANSI_1 "--**"
echo ANSI_10 "               This script is freeware and may be distributed*"
echo "*" ANSI_13 "!!! Please read the Notes and Warnings at the top of the script before using. !!!"
echo "*" ANSI_13 "!!! Use at your own risk. The author is not responsible for anything that may !!!"
echo "*" ANSI_13 "!!! or may not happen as a result of running this script.  You were warned.   !!!"
echo "*" ANSI_10 "                  This intro screen will only appear once."
echo ANSI_15 "*"
write "banner_voider.txt" $checkbanner
setdelaytrigger bannerdelay :promptcheck 5000
pause
end
# ----====[ End of show EGO banner :-) ]====----


# ----====[ Prompt Check! ]====----
# Checks to make sure you are starting at the Command Prompt
:promptcheck
cutText CURRENTLINE $location 1 7

if ($location <> "Command")
        echo ANSI_12 "**Must be run from the command prompt, moron!"
        halt
end

# ----====[ Set Initial vars, and Initilize sdsector.txt file ]====----
setvar $voidsec 11
getdate $datestamp
gettime $timestamp
write sdsector.txt $datestamp & " " & $timestamp
getinput $mincheck "Choose Minimum number of times sector appears for void check:" 5
getinput $maxcheck "Choose Max number of times sector appears for void check (0 = max):" 0
send "c"

# ----====[ Read in info from find_dock.ts into an array. ]====----
setvar $linecount 1
echo ANSI_10 "*BUILDING ARRAY...PLEASE WAIT..." ANSI_15 "*"
:makearray
read "sdfind.txt" $bigline $linecount
if $bigline = EOF
	goto :start
else
	getword $bigline $firstvar 1
	getword $bigline $secondvar 2
	setvar $voidsecarray[$firstvar] $secondvar
	add $linecount 1
	echo $linecount "*"
	goto :makearray
end

:start
setvar $voidcount 1
:getnextline
If $voidsec = 5001
	echo ANSI_10 "**all done!  Check your TWX directory for SDSECTOR.TXT. Good Luck!"
	send "q"
	getdate $datestamp
	gettime $timestamp
	write sdsector.txt $datestamp & " " & $timestamp
	halt
else
	if $maxcheck = 0
		goto :checkmin
	elseif $voidsecarray[$voidsec] > $maxcheck
		goto :skiptonext
	else
		goto :checkmin
	end
end

:checkmin
if $voidsecarray[$voidsec] < $mincheck
	goto :skiptonext
else	
	goto :skipline
end
	
:skipline
send "f1*" $voidsec "*"
settextlinetrigger 1 :checkvoids "is:"
settextlinetrigger 5 :noroute "Error - No"
pause
	:checkvoids
	killalltriggers
	settextlinetrigger 2 :getsecnums ">"
	setvar $hopcount 1
	pause
		:getsecnums
		killalltriggers
		setvar $wordcount 1
		:getnextsecnum
		getword CURRENTLINE $secnum $wordcount
		striptext $secnum "("
		striptext $secnum ")"
		if $secnum = $voidsec
			setvar $voidme $lastnum
			setvar $hops $hopcount
			goto :voidsecs
		else
			if $secnum = 0
				goto :checkfornextline
			else
				setvar $lastnum $secnum
				add $wordcount 2
				add $hopcount 1
				goto :getnextsecnum
			end
		end

:checkfornextline
settextlinetrigger 3 :getsecnums ">"
settextlinetrigger 4 :getsecnums $voidsec
pause

:voidsecs
killalltriggers
send "v" $voidme "*"
setvar $totalhops[$voidcount] $hops
add $voidcount 1
if $voidcount = 7
	write sdsector.txt $voidsec & " " & $totalhops[1] & " " & $totalhops[2]  & " " & $totalhops[3]  & " " & $totalhops[4]  & " " & $totalhops[5]  & " " & $totalhops[6]  & " " & $totalhops[7]
	goto :clearvoids
else
	goto :skipline
end

:clearvoids
send "v0*yy"
add $voidsec 1
goto :start

:noroute
killalltriggers
send "y"
add $voidsec 1
goto :start

:skiptonext
add $voidsec 1
goto :start